Read-Sensor-Resistances/nano_c_mk1/nano_c_mk1.ino

#include <Adafruit_ADS1X15.h>  // https://github.com/adafruit/Adafruit_ADS1X15, with partially its "continuous" example code integrated in ths

#define WAIT_TIME      1000UL  // default wait time each value read
#define ADS_MAX        4       // # of analog input pins of an ADS1115
#define VOLTAGE_RANGE  6.144f  // ADS1115 default gain (+/- 6.144V). Change this number smaller will reduced its actual magnutude, and vice versa
#define CONST_I2C      32768   // a constant value
#ifndef IRAM_ATTR
#define IRAM_ATTR
#endif

Adafruit_ADS1115 adc;
unsigned long currTime;  // non-blocking timer
int channel = 0;  // mux selector for which channel (AIN0-AIN3) to read the analog value from. See ADS1115 datasheet for details
float adcReadings[ADS_MAX];  // buffer to hold all values read from an adc
constexpr int READY_PIN = 3;  // pin # that connects the "ALRT" pin of the ADS1115 to the board
volatile bool new_data = false;  // "ready" flag for the ADS1115

/**************************************************************************/
/*!
    @brief  parse data from the ADS1115 and record to the buffer array

    Upon data recieved, call getLastConversionResults() once to record the
    value into the adcReadings array. Increment/cycle back the channel mux
    selector and call startADCReading() to read the next channel. set back
    the new_data flag back to false

    @acknowladgement https://github.com/RobTillaart/ADS1X15/blob/master/examples/ADS_continuous_4_channel/ADS_continuous_4_channel.ino
*/
/**************************************************************************/
void readData() {
  // we only wanna grab/set data if the ADS is ready to
  if (new_data) {  // for some reason it treat the last index to the zeroths and everything else off by 1
    // save the value
    adcReadings[channel == 0 ? ADS_MAX - 1 : channel - 1] = adc.getLastConversionResults();  // the lambda inside [] to set index to its correct position
    channel = (channel + 1) % ADS_MAX;  // request next channel #. Cycle back to zero if the number is larger than ADS_MAX (maybe must multiple of 2)
    adc.startADCReading(MUX_BY_CHANNEL[channel], true);
    new_data = false;  // toggle back the flag
  }
}

void IRAM_ATTR NewDataReadyISR() {  // interrupt to make it read data
  new_data = true;
}

void setup() {
  Wire.begin();
  Serial.begin(19200);
  adc.begin();
  pinMode(READY_PIN, INPUT);
  // "Ready" when on falling signal edge (negedge)
  attachInterrupt(digitalPinToInterrupt(READY_PIN), NewDataReadyISR, FALLING);  
  adc.startADCReading(MUX_BY_CHANNEL[channel], true);  // read once
  currTime = millis();  // record the current time
}

void loop() {
  readData();  // always read data from the ads1115
  if (millis() - currTime >= WAIT_TIME) {  // non-blocking time delay, giving ADC and everything else enough time to update
    // print the array, as we don't have internal method for it.
    Serial.print("[");
    for (int i = 0; i < ADS_MAX; i++)
    {
      Serial.print(adcReadings[i] * VOLTAGE_RANGE / CONST_I2C);
      if (i != ADS_MAX - 1) {  // fence-post the array print
        Serial.print(", ");
      }
    }
    Serial.println("]");
    currTime = millis(); // reset the current time
  }    
}